// CS3451 Computer Graphics
// P1 - Wheels
// Catherine Herrington & Douglas Miller
// http://www-static.cc.gatech.edu/grads/c/catyarr/wheels
// Created on May 23, 2006
// Wheels

// illusion of motion by J. Rossignac

int n=20;                         //Number of tubes in rings
boolean bSpiral = false;          //Draw rings in spirals vs circles
boolean bGrid = false;            //Draws original grid configuration vs circular configuration

void setup()                      //Executed at initialization
{
   size(800, 800);                //Size of screen in pixels
   rectMode(CENTER);              //Sets the first two params of rect to specify the center
};

void draw()                       //Executed continuously to refresh window
{ 
   background(255);               //Sets white background
   
   PFont fontA = loadFont("ScalaSans-Caps-32.vlw");   //Load the font 
   textFont(fontA, 16);                               //Set the font and its pixel size
   fill(0);                                           //Change color of the text
   text("Catherine Herrington", width-200, height-20);//Display team names
   text("Douglas Miller", width-150, height-40);      //Display team names

   translate(width/2,height/2);   //Sets the origin to center of the window

   int scaleFactor = 90;                              //Multiplier for x and y coordinates
   boolean bClockwise = true;                         //Determines if rings drift clockwise or counterclockwise

   if (bGrid)
   {
      //Display original configuration
      for (int x = -3; x <= 3; x += 2)   {
         for (int y = -2; y <= 2; y += 2)      {
            rings(x*scaleFactor, y*scaleFactor,bClockwise);
            bClockwise = ! bClockwise;
         }
      }
      for (int x = -2; x <= 2; x += 2)   {
         for (int y = -1; y <= 1; y += 2)      {
            rings(x*scaleFactor, y*scaleFactor,bClockwise);
            bClockwise = !bClockwise;
         }
      }
   }
   else
   {
      //Display circular configuration
      scale(1.3);
      rings(0, 0, bClockwise);  
      for (int i = 0; i < 6; i++)   {
         rotate(2*PI/6);
         rings((int)(1.9*scaleFactor), 0, bClockwise);
         bClockwise = ! bClockwise;                      //Alternate direction of drift
      }
      rotate(-2*PI/12);
      scale(0.6);
      for (int i = 0; i < 6; i++)   {
         rotate(2*PI/6);
         rings((int)(2.0*scaleFactor), 0, bClockwise);
         bClockwise = ! bClockwise;                      //Alternate direction of drift
      }
   }
};
   
void rings(int x, int y, boolean bClockwise) {     //Draws rings
   pushMatrix();                                   //Save coordinates system
   translate(x,y);                                 //Changes where the rings are drawn
   noStroke();
   fill(255, 255, 255);
   
   if (bSpiral)                          //If mouse button is pressed, draw rings in swirl configuration
   {
      ellipse(-4, -4, 200, 191);              //Clear area behind rings
      fill(0, 0, 0);                          //Change color to black
      ellipse(0, 0, 10, 10);                  //Draw small black dot in center of rings
      for (int j=1; j<n*15; j++) 
      {
         scale(pow(0.8, 1.0/n));                //Shrink a total of one ring's width for each full ring
         pushMatrix();                          //Save coordinates system
         rotate(PI*j*(2.0+1.0*mouseY/height)/n);//Go around the ring, with spacing dependent on mouse position
         translate(0, 100);                     //Draw tube at distance from center
         shape(11, 16, bClockwise);             //Draw tube
         popMatrix();                           //Restore coordinates system
      }
   }
   else                                       //If mouse button is not pressed, draw rings in circular configuration
   {  
      ellipse(0, 0, 177, 177);                //Clear area behind rings
      fill(0, 0, 0);                          //Change color to black
      ellipse(0, 0, 10, 10);                  //Draw small black dot in center of rings
      for (int j=1; j<15; j++)                //Loop for number or rings
      {
         scale(0.80);                         //Changes spacing between rings
         rotate(PI*(1.0+1.0*mouseY/height)/n);//Rotate rings based on mouse location
         for (int i=0; i<n; i++)              //Loop for number of tubes in a ring
         {
            pushMatrix();                     //Save coordinates system
            rotate(i*2.0*PI/n);               //Changes the spacing between tubes
            translate(0,100);                 //Changes maximum size of rings
            shape(11, 16, bClockwise);        //Changes size of tube
            popMatrix();                      //Restore coordinates system
         };
      };
   }; 
   popMatrix();                               //Restore coordinates system
};
   
void shape (float w, float L, boolean bClockwise)    //Draws tube
{ 
   pushMatrix();                       //Save coordinates system

   rotate(PI*0.5*mouseX/width);        //Rotate tube based on mouse location
   noStroke();                         //Stops drawing border around shapes

   //dark center of tube
   fill(0,0,0);                        //Color of dark center
   rect(0,0,1.0*L,2.0*w);              //Draw rectangle in center of tube
  
   //dark side of tube
   translate(L/2,0);                   //Move center by half of width
   if(bClockwise) {                    //Drift clockwise
      fill(240,185,195);}              //Color of light side of tube
   else {
      fill(50,130,125); }              //Color of dark side of tube
  
   ellipse(0,0,0.7*L,2*w);             //Draw dark ellipse
  
   //light side of tube 
   translate(-L,0);                    //Move center to other side of tube
   if(bClockwise) {                    //Drift clockwise
      fill(50,130,125); }              //Color of dark side of tube
   else {
      fill(240,185,195); }             //Color of light side of tube
   
   ellipse(0,0,0.7*L,2*w);             //Draw light ellipse
  
   popMatrix();                        //Restore coordinates system
};


void mousePressed()                    //Called when mouse button is pressed
{ 
  if( mouseButton == LEFT ) {          //Toggle spiral vs circular rings when left button is pressed
     bSpiral = ! bSpiral;
  }
  else if( mouseButton == RIGHT )      //Toggle grid vs circular configuration when right button is pressed
  {
    bGrid = ! bGrid;
  }
  
}